如何在DATA步中调用PROC？

slash

给大家介绍一种方法，可以在DATA步中调用PROC过程，这样就可以在DATA步中对PROC产生的结果进行操作。
具体如何实现？
首先肯定不是直接在DATA步中写PROC，有些人可能会说用CALL EXECUTE，其实不然。CALL EXECUTE是在DATA步运行之后才调用。


在这里给大家介绍RUN_MACRO这个函数，通过该函数就可实现在DATA步中调用PROC，或者是另一个DATA步。
顾名思义，该函数就是用来调用macro的，但它有它的独特之处：不能在DATA步中使用该函数，只能在FCMP过程中使用（自定义函数中使用）。


因此要实现在DATA步中调用PROC，需要三个步骤：

• 定义一个MACRO，其内容就是一个PROC过程；
• 通过FMCP创建自定义函数，调用上面定义的MACRO；
• 在DATA步中调用自定义函数，即间接调用PROC过程；
  

下面用一个例子来说明：

• 创建宏（该宏是利用PROC SQL创建一个数据集，包含一个变量的非重复值）
  

1. %macro distinct_values;
   
2.        %let input_table = %sysfunc(dequote(&input_table));
   
3.        %let column = %sysfunc(dequote(&column));
   
4.        %let output_table = %sysfunc(dequote(&output_table));
   
5.        proc sql;
   
6.        create table &output_table as
   
7.        select distinct &column
   
8.        from &input_table;
   
9. %mend;

复制代码

• 创建自定义函数（在自定义函数中调用上面定义的宏）
  

1. proc fcmp outlib=work.funcs.sql;
   
2.        function get_distinct_values(input_table $, column $, output_table $);
   
3.        rc = run_macro('distinct_values', input_table, column, output_table);
   
4.        return (rc);
   
5.        endsub;
   
6. run;

复制代码

• 在DATA步中调用
  

1. options cmplib = work.funcs;
   
2. data _null_;
   
3.         rc = get_distinct_values('sashelp.shoes', 'region', 'work.regions');
   
4.         id=open('work.regions');
   
5.         if id then nobs=attrn(id,'NOBS');
   
6.         put nobs;
   
7. run;

复制代码

通过这种方式就可在DATA中调用PROC，从而使用PROC生成的结果。在上面的例子中，最后的DATA步调用PROC生成了数据集WORK.REGIONS，
然后通过OPEN函数打开该数据集，获取到该数据集的观测数。当然你可以干其他的事情。


重点在于：RUN_MACRO调用宏后，会一直等待宏执行完毕后才返回。因此紧接着get_distinct_values自定义函数后就可以使用宏产生的数据。
如果使用CALL EXECUTE调用宏，是在DATA步执行完之后，才调用宏，实际上就是在DATA步之后增加了宏的调用。


注：虽然在第三步调用get_distinct_values之后就可以使用该数据，但不能使用SET WORK.REGIONS; 为什么呢？这是因为SET语句的运行机制决定的。
在程序编译阶段，如果有SET语句，就会将SET的数据集打开，但此时程序还未执行，数据集根本没有生成，因此就会报错，提示数据集不存在。
所以要使用OPEN函数，来对该数据集进行操作。

yinhuagang

学习了！