求教SAS的几道基础题

shiyiming

我是一名在校学生，学软件的，选了一门sas的课，由于专业课的课程实践项目比较多，所以平时都没去上过课，交作业的时间要到了，没时间去从头学，希望大家帮帮忙：
2．建立一个数据集名为AAA，其中有变量A1,A2,A3,给定数据为：75 60 55 44 75 64 85 68 66 55 36 29 57 88 63 为其建立的数据步，以ABC2.SAS存放。

3.在程序中用file命令产生文件以为名lx的数据文件保存在磁盘中，程序文件以ABC3.SAS存放。
Num    name               w  
  201     zhanglan         55
  202     linying             60
  203     zhouyong        68
  204     wangyan         45
4.某班有15个同学期未的计算机成绩如下: 66 78 82 68 102 45 88 64 93 55 71 -62 102 92 83 建立数据集zq,若成绩大于100或小于0的数据不进入数据集，将该程序以ABC4.sas存放。

1.120人的计算机上机成绩， 试用SAS中UNIVARIATE过程进行成绩的正态分布的检验。
86 83 77 81 81 80 79 82 82 65 81 87 82 78 80 81
87 81 77 78 77 78 77 77 77 71 95 78 81 79 80 77
76 82 80 82 84 79 90 82 79 82 50 86 76 78 83 75
82 78 62 83 81 81 83 89 81 86 82 82 78 84 84 84
81 81 74 78 64 80 74 78 75 79 95 75 74 71 88 82
55 85 73 78 81 99 77 78 81 87 83 65 64 78 75 82
80 80 77 81 75 83 90 80 85 81 88 78 82 84 85 84
82 85 84 82 85 84 78 90
保存程序名为ABC5.SAS

2.为整治农贸市场的斤两短缺现象，相关部门在市场随机抽取100家摊位进行抽查测试，其含短缺(％)的资料整如下：
频数   6     8      11       14     20      12       8       6       4
值 4.5  5.5     6.5     7.5    8.5      9.5     10.5     11.5    12.5
请问数据服从正态分布吗？保存程序名为ABC6.SAS

1.为了解计算机对人体的辐射情况，随机获得10人的不同距离的皮肤静电感应的相关数据：
                   1       2     3      4      5      6      7      8       9      10
0.3   米内   3.4   3.0   4.5   4.5   3.8   3.3  3.6   4.0   3.3    3.3
        米外   2.2    2.3   2.4   2.0   2.4   2.1  2.0   1.9   2.4    2.0
能否认为距离将减少的辐射对人体的伤害? 保存程序名为ABC7.SAS.

2.为了分析高等数学的期终试卷A,B试卷的难易度有无差别,将试卷发给随机抽选的28名同学测试,两套测得成绩为:
A卷成绩 66 65 68 68 67 67 80 77 81 89 96 78 67 56 45 60 66 78 87 76 74 75 80 54 90 81 78 63
B卷成绩 65 67 66 64 61 66 78 79 81 82 69 76 68 58 42 61 64 84 75 83 55 80 71 62 66 83 74 50
保存程序名为ABC8.SAS.

3.今测得12名正常人和15名病毒性肝炎患者血清转铁蛋白(g/L)的含量,结果如下，问患者和健康人的转铁蛋白是否有显著性差别?
  正  常  人 2.65 2.72 2.85 2.91 2.55 2.76 2.82 2.69 2.64 2.73 2.71 2.61
  病毒性肝炎患者 2.36 2.15 2.52 2.25 2.28 2.31 2.53 2.19 2.34 2.31 2.41 2.22 2.57 2.61 2.24
保存程序名为ABC9.SAS.

4. 电信局使用两种不同的通讯设备传递信号，试问通过下组测试数据能否说明设备间存在显著的不同？保存程序名为ABC10.SAS.
A 30 B 32 A 20 B 40 A 25 B 40 A 25 B 38 A 30 B 25 A 35 B 40  A  25 B 40 A 20 B 55 A 25 B 60 A 25 B 55 A 30 B 58 A 35 B 64 A  30 B 30 A 20 B 40 A 30 B 55 A 18 B 20 A 10 B 50 A 20 B 45

1.某农场中种有苹果、梨、橙及柚等多种水果，为研究其吸附有害物氨的差异。对苹果、梨、橙及柚水果各做了5次试验，试问这几种水果吸附氨的量均数是否不同？
       各种水果吸附氨的量
————————————————————   
         苹果   梨     橙      柚
         1.3   1.6    1.0     0.9
         2.5   1.7    2.1     1.8
         1.4   1.0    1.5     1.2
         1.8   1.5    1.2     1.3
         2.0   1.7    1.4     1.5
保存程序名为ABC11.SAS.

2. 有三台机器生产规格相同的铝合金薄板，为检验三台机器生产薄板的厚度是否相同，随机从每台机器生产的薄板中各抽取了5个样品，测得结果如下：
机器1：0.236,0.238,0.248,0.245,0.243
机器2：0.257,0.253,0.255,0.254,0.261
机器3：0.258,0.264,0.259,0.267,0.262
问：三台机器生产薄板的厚度是否有显著差异？
保存程序文件名为ABC12.SAS.

1某社区调查了120名市民，考察性别与对吸烟态度之间的关系，试将所得资料作成相对频数的联合分布、边际分布和条件分布列联表，并进行相关分析。保存程序文件名为ABC13.SAS
                        性别与对吸烟的态度
态度Y 性别X 合计
男 女
容忍 48 8 56
反对 20 44 64
合计 68 52 120


2.假设某市高中把学生分成实验班与普通班，任课的老师完全一样；唯一不同的是实验班的教学加重实验室的操作与自已准备实习，普通班的教法则采用传统式的授课、抄笔记、做家庭作业等。高考后，升学的人数百分比如下.实验班的教学方法是否比普通班更有效?保存程序文件名为ABC14.SAS
                 教学法 上榜人数       落榜人数    总数
  实验班  55         5           60
          普通班  30         30           60
  总数    85         35          120
3.以下是生活期望值与个人成就的抽样调查,求：相关系数和回归直线。保存程序文件名为ABC15.SAS
生活期望值 10 8 7 6 4 3 2 1
个人成就 7 9 10 4 2 1 3 2

shiyiming

这种题很简单！

shiyiming

这些题对于我这样的老人来说实在太难了，好多都已经忘记了。所以只书写一部分程序，仅供参考，如有错误，若影响你成绩，概不负责。
还有我只给出程序，对于运行结果，我也不做解释，实在害怕误人子弟，所以还是不说为妙。因为统计结论用语有时候很敏感，诸如在某置信水平下，不能接受原假设。。。。，千万不能用很肯定的语气。
还有一个就是本人水平有限，有些题目解不出来了，比如说其中的两样本均值的单边检验，还有列链表的分析等。。。我都已经无能为力，理论不扎实啊。。。。。。有些题目即使写出来了，但是也有可能是错误的，
所以请见谅。还有有些前提检验（比如说数据是否符合正泰分布），我都没进行，所以你有必要去做一些正泰行检验，比如说正泰检验通过了，还要进行同方差检验等。。。。。。
总之，有好多话要补充，但是表达能力有限，希望对你解题有所帮助：
[code:1fc9i69m]                                /*********************/
                                /*      ABC2.SAS     */
                                /*********************/
data aaa;
        input A1-A3 @@;
        cards;
75 60 55 44 75 64 85 68 66 55 36 29 57 88 63
;
run;

                                /*********************/
                                /*      ABC3.SAS     */
                                /*********************/
data _null_;
        file "d:\lx.txt" dlm="";
        input Num:$3. name:$25. w;
        if _n_=1 then put 'Num name w';
        put num name w;
        cards;
201 zhanglan 55
202 linying 60
203 zhouyong 68
204 wangyan 45
;
run;

                                /*********************/
                                /*      ABC4.SAS     */
                                /*********************/
data zq;
        input score @@;
        if score>100 or score<0 then delete;
        cards;
66 78 82 68 102 45 88 64 93 55 71 -62 102 92 83
;
run;

                                /*********************/
                                /*      ABC5.SAS     */
                                /*********************/
data ex5;
         input score @@;
         cards;
86 83 77 81 81 80 79 82 82 65 81 87 82 78 80 81
87 81 77 78 77 78 77 77 77 71 95 78 81 79 80 77
76 82 80 82 84 79 90 82 79 82 50 86 76 78 83 75
82 78 62 83 81 81 83 89 81 86 82 82 78 84 84 84
81 81 74 78 64 80 74 78 75 79 95 75 74 71 88 82
55 85 73 78 81 99 77 78 81 87 83 65 64 78 75 82
80 80 77 81 75 83 90 80 85 81 88 78 82 84 85 84
82 85 84 82 85 84 78 90
;
run;
proc univariate data=ex5 normal;
        var score;
run;

                                /*********************/
                                /*      ABC6.SAS     */
                                /*********************/
data ex6;
        length freq value 8;
        input value @@;
        freq=lag9(value);
        if _n_>9;
        cards;
6 8 11 14 20 12 8 6 4
4.5 5.5 6.5 7.5 8.5 9.5 10.5 11.5 12.5
;
run;

proc univariate data=ex6 normal;
        var value;
        freq freq;
run;

                                /*********************/
                                /*      ABC8.SAS     */
                                /*********************/
data ex8;
        length testA testB 8;
        input testB @@;
        testA=lag28(testB);
        if _n_>28;
        cards;
66 65 68 68 67 67 80 77 81 89 96 78 67 56 45 60 66 78 87 76 74 75 80 54 90 81 78 63
65 67 66 64 61 66 78 79 81 82 69 76 68 58 42 61 64 84 75 83 55 80 71 62 66 83 74 50
;
run;
proc ttest data=ex8;
        paired testA*testB;
run;

                                /*********************/
                                /*      ABC9.SAS     */
                                /*********************/
data ex9(drop=i);
infile cards;
input type:$30. @;
if _n_=1 then do i=1 to 12;
        input score @;
        output;
end;
else
if _n_=2 then do i=1 to 15;
        input score @;
        output;
end;
cards;
正常人 2.65 2.72 2.85 2.91 2.55 2.76 2.82 2.69 2.64 2.73 2.71 2.61
病毒性肝炎患者 2.36 2.15 2.52 2.25 2.28 2.31 2.53 2.19 2.34 2.31 2.41 2.22 2.57 2.61 2.24
;
run;
proc ttest data=ex9;
        var score;
        class type;
run;

                                /*********************/
                                /*      ABC11.SAS    */
                                /*********************/
data ex11(drop=a1-a4);
        length pinzhong $4;
        label pinzhong="水果类别";
        label num="吸附氨量";
        input a1-a4;
        pinzhong="苹果";
        num=a1;
        output;
        pinzhong="梨";
        num=a2;
        output;
        pinzhong="橙";
        num=a3;
        output;
        pinzhong="柚";
        num=a4;
        output;
        cards;
1.3 1.6 1.0 0.9
2.5 1.7 2.1 1.8
1.4 1.0 1.5 1.2
1.8 1.5 1.2 1.3
2.0 1.7 1.4 1.5
;
run;
proc anova data=ex11;
        class pinzhong;
        model num=pinzhong;
        means pinzhong /tukey;
run;
quit;
                                /*********************/
                                /*      ABC12.SAS    */
                                /*********************/
data ex12;
        infile cards dlm=',';
        if _n_=1 then machine='机器1';
        else if _n_=2 then machine='机器2';
        else if _n_=3 then machine='机器3';
        do i=1 to 5;
                input value @;
                output;
        end;
        drop i;
        cards;
0.236,0.238,0.248,0.245,0.243
0.257,0.253,0.255,0.254,0.261
0.258,0.264,0.259,0.267,0.262
;
run;
proc anova data=ex12;
        class machine;
        model value=machine;
        means machine /tukey;
run;
quit;


                                /*********************/
                                /*      ABC15.SAS    */
                                /*********************/
data ex15;
        length x y 8;
        input y @@;
        label x="生活期望值";
        label y="个人成就";
        x=lag8(y);
        if _n_>8;
        cards;
10 8 7 6 4 3 2 1
7 9 10 4 2 1 3 2
;
run;
proc corr data=ex15;
        var x;
        with y;
run;
proc glm data=ex15;
        model y=x;
run;quit;
[/code:1fc9i69m]

还有一些没做完的，或者做错的，希望论坛的朋友继续指正和加以补充。

shiyiming

byes，我拜您为师吧，楼上那么刁钻的问题您全给答出来了，还忒有条理，一看就是专业出身又有多年工作浸淫的成功人士。其他呢，还忒有爱心，帮没空做功课的小年轻当枪手。
会不会辱没师们我不敢打包票，但请您一定收下咱！

shiyiming

题目应该都是基础性的，但是相比那位只说了太简单三个字的伙计来说，Bayes的确为人非常热情，我也来班门弄斧补充没有做的一题：
ABC13:

data zhiyong;
length sex $6 atitu $3;
input sex  atitu  freq;
cards;
male dur 48
male opp 20
female dur 8
female opp 44
;
run;

proc freq data=zhiyong;
weight freq;
   tables sex*atitu
          / chisq expected cellchi2 nocol nopercent;

run;

另外，提个小小的建议，最后一题ABC15，用proc reg相对更好一些。不知道大家有没有注意，楼主这些题目之所以简单，是因为所有的实验设计都是均衡设计，所以什么anova分析，相关分析，回归分析都是用来干这些事情的。对非均衡设计，才动用glm过程。当然不是说glm过程不能用来做均衡设计。

shiyiming

还有，我非常赞成Bayes的一句话，就是做统计出身的不能把话说死，这就是为什么人大的吴喜之教授在招收博士生的时候总喜欢考一些看似简单实际非常难以答好的基础题。比如，假如:置信区间是[10,20]，置信度是95%,此时我们能不能说“我们可以相信真值将有95%的可能性落到区间[10,20]？”，为这道题落马的人不在少数。那些很多旁门左道出身的人一做模型，结果一出来就直奔p-value.认为只要p-value小就好，再问什么叫p-value，答：不知道。

shiyiming

非常感谢2楼大师，大师的为人我十分钦佩，想必大师应该是一位慈父吧，对我们年轻人的错误没有指责，没时间做作业是我的错，至于您做得如何都不重要，总之我很感谢您。