问题请假，谢谢！

shiyiming

[quote="mymine":2x0joz73]然后如果变量N多，且变量名没有规律的
有没有不用一个一个变量名输入的方法！[/quote:2x0joz73]
你仔细体会一下我的程序，答案就在里面！！！
可以的。

shiyiming

[code:3e2mueao]
/*假设你的第一个项目为a，最后一个项目为m，一共有50个项目*/

proc means data=a nway noprint;
   var a--m;
   class name;
   output out=aa(drop=_type_ _freq_) range=r1-r50;
run;
data result(drop=r1-r50 i) ;
   set aa;
   array r{50} r1-r50;
   array v{50} $;
   do i=1 to dim(r);
   if r(i) then v(i)='N';
   else v(i)='Y';
   end;
run;

[/code:3e2mueao]

最后变量v1-v50分别记录了50个项目的情况，不知道能否满足你的要求

shiyiming

这个程序不错，不用逐个输入各个变量名
不过里面部分程序还看不懂呵呵

shiyiming

谢谢哦，我在体会一下哈

shiyiming

如果你想把v1-v50还是用原来项目的变量名，请参考以下程序（还是以50个变量为例子）：
[code:334jje0v]
data _null_;
        length val $800;
        dsid=open('a');
        array tt{50} $20;
        do i=1 to 50;
        tt(i)=varname(dsid,i+1);
        end;
        val=catx('',of tt1-tt4);
        call symput('val',trim(left(val)));
        rs=close(dsid);
run;
proc means data=a nway noprint;
   var &val;
   class name;
   output out=aa(drop=_type_ _freq_) range=r1-r50;
run;
data result(drop=r1-r50 i) ;
   set aa;
   array r{*} r1-r50;
   array v{*} $ &val;
   do i=1 to dim(r);
   if r(i) then v(i)='N';
   else v(i)='Y';
   end;
run;

[/code:334jje0v]

shiyiming

[code:3695cfor]data aa;
input name $ a  b c d ;
cards;
XX 1 2 3 4
XX 1 2 3 4
XX 2 2 3 4
YY 1 1 1 1
YY 1 1 1 2
ZZZ 3 3 3 3
ZZZ 3 3 3 3
ZZZ 3 3 3 3
ZZZ 3 3 3 3
;
proc sort;by name;run;

proc sql noprint;
select count(name) into :n from sashelp.vcolumn
where libname='WORK' and memname='AA' and type='num';
select name into :name separated by ' ' from sashelp.vcolumn
where libname='WORK' and memname='AA' and type='num';
quit;

data bb(drop=&name i x);
set aa;by name;
array aa _numeric_;
array bb(&n);
do i=1 to  dim(aa);
x=lag(aa(i));
if aa(i)-x=0 then aa(i)=.;
if first.name then aa(i)=.;
bb(i)=aa(i);
end;
run;
run;

data cc(keep=name &name);
set bb;by name;
array aa _numeric_;
array bb(&n) $ &name;
retain &name;
do i=1 to &n;
if aa(i) ne . then bb(i)='N';
if first.name then bb(i)=' ';
end;
if last.name;
run;
[/code:3695cfor]

shiyiming

在byes的程序基础上用点macro，means在这儿确实可以减少步骤
[code:2d9g9f37]data aa;
input name $ a  b c d ;
cards;
XX 1 2 3 4
XX 1 2 3 4
XX 2 2 3 4
YY 1 1 1 1
YY 1 1 1 2
ZZZ 3 3 3 3
ZZZ 3 3 3 3
ZZZ 3 3 3 3
ZZZ 3 3 3 3
;
run;
proc sql noprint;
select put(count(name),5.-L)  into :n from sashelp.vcolumn
where libname='WORK' and memname='AA' and type='num';
select name into :name separated by ' ' from sashelp.vcolumn
where libname='WORK' and memname='AA' and type='num';
quit;

proc means data=aa nway noprint;
   var &name;
   class name;
   output out=bb(drop=_type_ _freq_) range=r1-r&n.;
run;


data result(drop=r1-r&n. i) ;
   set bb;
   array r{&n} r1-r&n.;
   array v{&n} $ &name;
   do i=1 to dim(r);
   if r(i) then v(i)='N';
   end;
run;
[/code:2d9g9f37]

shiyiming

[code:3b8kq62v]data ahuige;
  input name$  a$ b$ c$ d$;
  cards;
XX 1 2 3 4 ……
XX 1 2 3 4 ……
XX 2 2 3 4 ……
YY 1 1 1 1 ……
YY 1 1 1 2 ……
ZZZ 3 3 3 3 ……
ZZZ 3 3 3 3 ……
ZZZ 3 3 3 3 ……
ZZZ 3 3 3 3 ……
;
run;

proc sql;
  select compbl(', case when max('||name||')<>min('||name||') then "N" else "" end as '|| name) into :statement separated by ''
  from sashelp.vcolumn
  where memname='AHUIGE' and libname='WORK' and name<>'name'
  ;

proc sql;
  create table final as
  select name &statement
  from ahuige
  group by name
  ;[/code:3b8kq62v]

shiyiming

这个帖子可真够热的，已经演化成了高手飚程序了，连ahuige都出手了，呵呵呵。

shiyiming

谢谢大家的支持哈
我用了其中一两种程序实现了我的目的
后面的程序有些难度挺大的，还没有看明白
再学习学习，谢谢哦！