请教：利用nodupkey可以去重复数据，但有没有简单办法把重复数据挑出来

shiyiming

/**********************
利用nodupkey可以去重复数据，但有没有简单办法把重复数据挑出来，例如：
************************/
data abs;
input blh  $15. ksdm $15. rq yymmdd10.;
cards;
PID000529036        8楼儿童病区        2012-3-13
PID000529036        ICU                        2012-3-13
PID000529036        ICU                        2012-3-14
PID000529036        ICU                        2012-3-15
PID000529036        6楼儿童病区2        2012-3-13
PID000531543        8楼儿童病区        2012-3-14
PID000531543        ICU                        2012-3-15
PID000531543        ICU                        2012-3-16
;

只显示出重复的部分（相同时间，相同地点），例如：
PID000529036        ICU                        2012-3-15
PID000531543        ICU                        2012-3-15

shiyiming

[code:2b25p2fh]

data abs;
input blh $12. ksdm : $ 15. rq yymmdd10.;
cards;
PID000529036 8楼儿童病区 2012-3-13
PID000529036 ICU 2012-3-13
PID000529036 ICU 2012-3-14
PID000529036 ICU 2012-3-15
PID000529036 6楼儿童病区2 2012-3-13
PID000531543 8楼儿童病区 2012-3-14
PID000531543 ICU 2012-3-15
PID000531543 ICU 2012-3-16
;

proc sort data=abs out=one;
  by ksdm rq;
run;

data two three;
set one;
by ksdm rq;
if first.rq ^=last.rq then output two;
else output three;
run;



[/code:2b25p2fh]

shiyiming

神一般的回答，没想到可以这样解决，谢谢版主！

shiyiming

如果还有其他好的办法，请继续指教！拓展下视野

shiyiming

data abs;
input blh $12. ksdm : $ 15. rq yymmdd10.;
cards;
PID000529036 8楼儿童病区 2012-3-13
PID000529036 ICU 2012-3-13
PID000529036 ICU 2012-3-14
PID000529036 ICU 2012-3-15
PID000529036 6楼儿童病区2 2012-3-13
PID000531543 8楼儿童病区 2012-3-14
PID000531543 ICU 2012-3-15
PID000531543 ICU 2012-3-16
;
run;

proc sql;
   create table aa as
   select a.*
   from abs as a
   group by blh,ksdm
   having count (ksdm)>=2;
quit;

这样应该也可以找到重复的数据。找出重复接受同类治疗的患者~

shiyiming

感谢linkidy的回复，我运行你的代码，没有得到我想要的结果，我也想过这种方法，似乎行不通

shiyiming

linkidy的方式是对的
[code:6rw6p95l]
proc sql;
create table aa as
select a.*
from abs as a
group by ksdm,rq
having count (rq)>=2;
quit;
[/code:6rw6p95l]

shiyiming

感谢linkidy的思路，感谢版主的帮助。
这个思路可以作为解决这类问题办法之一，值得借鉴，再次感谢！

shiyiming

[code:26evcp83]
data abs;
input blh $12. ksdm : $ 15. rq yymmdd10.;
cards;
PID000529036 8楼儿童病区 2012-3-13
PID000529036 ICU 2012-3-13
PID000529036 ICU 2012-3-14
PID000529036 ICU 2012-3-15
PID000529036 6楼儿童病区2 2012-3-13
PID000531543 8楼儿童病区 2012-3-14
PID000531543 ICU 2012-3-15
PID000531543 ICU 2012-3-16
;

proc sql;

create table one as
select *
from abs
order by
ksdm,rq;

create table two as
select *, monotonic() as id
from one;

create table three as
select *
from two
group by ksdm,rq
having max(id)^=min(id);

alter table three drop id;

quit;
[/code:26evcp83]

shiyiming

版主的第一种方法是求出相同数据的第一条和最后一条数据,如果要输出所有的重复值,需要修改判断语句如下:
将语句
if first.rq^=last.rq then output two;
修改为:
if first.rq^=last.rq or (last.rq =0 and first.rq=0) then output two;