SAS中文论坛

标题: 关于'array'用法 [打印本页]

作者: shiyiming 时间: 2009-12-17 11:39
标题: 关于'array'用法
有一个dataset m:
y  x  c
2  4  12
2  5  16
3  2  10
3  6 21
4  1  19
7  3  14
现在想把m 变成 dataset n:
x 1 2 3 4 5 6
y
2                      12  16
3          10                   21
4    19
7                14
也就相当于把m中的x变成横向排列,y保持不变,然后将(x,y)一一对应的c放在对应的位置上(x,y).
我尝试了array,尝试arrayc(6,6)=c,好像这里有问题,未能成功,请高手指点.谢谢!

作者: shiyiming 时间: 2009-12-17 11:45
标题: Re: 关于'array'用法
由于排版的问题,上面的n会产生误解,在这说明一下,c的值由(x,y)来决定,而且,也排在对应的(x,y)的坐标上.
比如,12, 16分别在(x=2,y=4),和(x=2,y=5)的位置上.

作者: shiyiming 时间: 2009-12-17 12:07
标题: Re: 关于'array'用法
[code:2y7oqcdt]data m;
input y x c;
datalines;
2 4 12
2 5 16
3 2 10
3 6 21
4 1 19
7 3 14
;

proc transpose data=m out=n prefix=x_;
by y;
id x;
var c;
run;

data n;
retain y x_1-x_6;
set n;
drop _name_;
run;[/code:2y7oqcdt]

作者: shiyiming 时间: 2009-12-17 12:41
标题: Re: 关于'array'用法
赠品: array版本的
[code:y7qs04hm]%let n=6;
data n2(drop=x c);
retain y;
array arr{&n} x_1-x_&n;
do _n_=1 by 1 until(last.y);
set m;
by y;
arr(x)=c;
end;
run;[/code:y7qs04hm]

欢迎光临 SAS中文论坛 (https://mysas.net/forum/)