data a2;
set a1;
year_data = year(rq);
month_data = month(rq);
run;
proc sql;
create table a3 as
select max(rq) as rq
from a2
group by year_data, month_data ;
quit;
proc print data = a3 ;
format rq yymmdd10. ;
run;作者: shiyiming 时间: 2008-11-7 00:44 标题: Re: 请教;如何筛选出每个月最后一天 if it's already sorted by rq, then
[code:398rkign]
data b(keep=rq);
set a1 (keep=rq rename=(rq=cur_rq)) end=eof;
rq = lag(cur_rq);
if _n_>1 then
if intnx('month', rq, 1, 'beginning') le cur_rq then
output;
if eof then do;
rq = cur_rq;
output;
end;
run;
[/code:398rkign]
it just has as many steps as LSD did.作者: shiyiming 时间: 2008-11-7 10:58 标题: Re: 请教;如何筛选出每个月最后一天 [code:cexqxxjd]proc sort data=a1;
by descending rq;/*选第一天就不用sort了*/
run;
data a2;
set a1;
if dif(month(rq)) ne 0;
run;[/code:cexqxxjd]
不知道是不是简单了点儿 <!-- s:) --><img src="{SMILIES_PATH}/icon_smile.gif" alt=":)" title="Smile" /><!-- s:) -->作者: shiyiming 时间: 2008-11-7 18:50 标题: Re: 请教;如何筛选出每个月最后一天 sql实现的话，就一个sql就行了，不需要前面的data步作者: shiyiming 时间: 2008-11-7 20:21 标题: Re: 请教;如何筛选出每个月最后一天 i see, the CALCULATED keyword
[code:1pblpcok]
proc sql;
select rq from(
select max(rq) as rq format=yymmdd10., month(rq) as month, year(rq) as year
from a
group by CALCULATED year, CALCULATED month
);
quit;
[/code:1pblpcok]
or
[code:1pblpcok]
proc report data=a nowd out=b(keep=rq);
column rq rq=month;
define rq/max format=yymmdd10.;
define month/group format=yymmn6.;
run;
[/code:1pblpcok]作者: shiyiming 时间: 2008-11-7 22:29 标题: Re: 请教;如何筛选出每个月最后一天 兄弟，真是强悍啊。
继续
sql用一个select就可以了，不用嵌套select作者: shiyiming 时间: 2008-11-8 05:37 标题: Re: 请教;如何筛选出每个月最后一天 真的不知道怎么办了，byes别折磨人了。料就这么多，要不为什么上面的怎么搞都没事，咱家只是拉了拉幼齿就栽了呢？
[code:1bf4b3y9]
proc means data=a noprint max;
class rq;
var rq;
format rq yymmS7.;
ways 1;
output out=xxx(drop=_type_ _freq_) max=max_rq;
run;
[/code:1bf4b3y9]
or
[code:1bf4b3y9]
proc univariate data=a noprint;
class rq;
var rq;
format rq yymms7.;
output out=xxx max=max_rq;
run;
[/code:1bf4b3y9]
or if it's sorted then
[code:1bf4b3y9]
data xxx;
set a;
by rq groupformat;
if last.rq;
format rq yymms7.;
run;
[/code:1bf4b3y9]作者: shiyiming 时间: 2008-11-8 10:18 标题: Re: 请教;如何筛选出每个月最后一天 上面最有一个data步正是我想要的。牛人。
五体投地作者: shiyiming 时间: 2008-11-12 06:48 标题: Re: 请教;如何筛选出每个月最后一天 byes过奖了！跟您的指导是分不开的。