SAS中文论坛

标题: Kruskal-Wallis test 实例程序 [打印本页]

作者: shiyiming 时间: 2008-10-2 14:10
标题: Kruskal-Wallis test 实例程序
/*Create Database*/

data sample ;

do group = 1 to 8 ;

input n@@;

do j=1 to n;

  input x @@;

  output;

end ;

end;

cards ;
7 35.96 35.48  39.33  39.35  39.71  34.21  40.26
7 61.8 62.9 55.66  53.68  66.18  44.74  51.85
7 80.9 80.65  63.21  71.58  67.65  56.41  59.26
7 100.73  96.77  87.91  85.37  82.26  59.79  72.22
7 106.57  95.16  85.71  82.93  93.55  57.73  75.93
7 80.9 77.42  75.82  83.6 80.65  61.54  53.33
7 66.29 53.23  64.84  65.61  56.45  42.86  46.67
7 82.02 82.26  71.43  64.83  70.97  52.75  58.33
;

/*调用FREQ过程*/

proc freq ; /*the correct result is "row mean scores differ"*/

tables group*x/ scores = rank cmh2 noprint;

run; /*row mean scores differ=18.13*/

/*调用NPAR1WAY过程*/

proc npar1way wilcoxon;

class group; /* Chi-Square= 18.13*/

var x;

run;

/*RANK+ANOVA过程,同时进行两两比较，LSD*/

proc rank data =sample out = a ;

var x;

ranks r;

proc anova;

class group ;

model r = group ;

means group/ snk ; /*LSD方法进行两两比较*/

run;

quit; /* R-Square*DF总= 0.625172*29=18.13*/

作者: shiyiming 时间: 2008-10-2 14:14
标题: Re: Kruskal-Wallis test 实例程序
由于各个样本的总体呈偏态分布或方差不齐,无法使用方差分析中的两两比较，检验其总体分布是否相同，常用的非参数秩和检验方法是Kruskal-Wallis 法,在SAS 软件中实现的过程步有以下三种方法: NPAR1 WAY 过程、FREQ过程以及RAN K 和ANOVA 两过程的结合，而样本间两两比较则可以通过RAN K 和ANOVA 两过程的结合,采用MEANS 语句来实现，即先对原始数据进行排序，求相应的秩次，然后对秩进行参数的多重比较。

作者: shiyiming 时间: 2008-10-2 14:14
标题: Re: Kruskal-Wallis test 实例程序
上面是实用原则

欢迎光临 SAS中文论坛 (https://mysas.net/forum/)