问一个merge问题

shiyiming

to wl1017
这个可以得到我想要的结果，不过就是需要插入连续变化的var1。

shiyiming

终于实现只在一个data步中的序列填充。供各位参考，欢迎修改意见。
[code:25b9wtq2]data raw;
   input name $ var1 var2;
   datalines;
A 1 3
A 3 4
A 5 2
B 2 1
B 4 0
C 3 6
;
run;

proc sort data=raw out=raw_sorted;
by name var1;
run;

data temp(drop=i j /*var1_*/);
        do i=1 to 5 by 1;
                retain var1 1;
                set raw_sorted(rename=(var1=var1_)) end=eof;
                by name;
                if first.name then do;
                        if last.name then do;
                                do j=1 to 5;
                                        var1=j;
                                        output;
                                end;
                        end;
                        else do;
                                do j=1 to var1_;
                                        var1=j;
                                        output;
                                end;
                        end;
                end;
                else do;
                        var1=var1+1;
                        if last.name then do;
                                if var1=5 then do;
                                        do j=var1 to 5-1;
                                                var1=j;
                                                output;
                                        end;
                                        var1=var1_;
                                        output;
                                end;
                                else do;
                                        do j=var1 to 5;
                                                var1=j;
                                                output;
                                        end;
                                end;
                        end;
                        else do;
                                do j=var1 to var1_;
                                        var1=j;
                                        output;
                                end;
                        end;
                end;
        end;
run;

[/code:25b9wtq2]

shiyiming

我的方法， 一共7行代码，可扩展性也比较好：

data raw;
   input name $ var1 var2;
   datalines;
A 1 3
A 3 4
A 5 2
B 2 1
B 4 0
C 3 6
;
run;

proc freq data=raw noprint;
     table name *var1/sparse out=_new(drop=COUNT PERCENT);         
run;

data new;
      merge raw  _new;
      by name var1;
run;

shiyiming

[quote="byes":3nofhcxa]no,no,no
just only a data step
proc sql not nedded[/quote:3nofhcxa]
莫非是用hash object? 不确定...
[code:3nofhcxa]data raw;
        input name $ week var1 var2;
        datalines;
A 3 1 3
A 5 3 4
A 53 5 2
B 2 1 .
B 26 0 3
C 1 6 .
;

data temp(drop=rc i);
        length name $8;
        if _n_=1 then do;
                declare hash h(dataset:"raw",hashexp:16);
                rc=h.defineKey('name','week');
                rc=h.defineData('name','week','var1','var2');
                rc=h.defineDone();
                call missing(name,week,var1,var2);
        end;
        set raw(keep=name week);
        by name;
        if first.name then do;
                do i=1 to 53;
                        rc=h.find(key:name,key:i);
                        week=i;
                        output;
                        call missing(of var:);
                end;
        end;
run;[/code:3nofhcxa]

shiyiming

why 'do i=1 to 53'? intended to cover all possible values?
all the code fragments above using so called one-step DATA STEP assumed that you've already known the max value of week, so that you can fill-the-holes. In case this is unknown, the data has to be passed twice, so that whether you enclose that two pass in one DATA STEP or not really doesn't matter.

shiyiming

我假定你只需要所有出现在数据中的Var1的值，而不必连续，比如0-7，9-11，而8没有出现，你不需要为每个名字都添加一行 var1=8。

data raw;
   input name $ week var1 var2;
   datalines;
A 3 1 3
A 5 3 4
A 53 5 2
B 2 1 .
B 26 0 3
C 1 6 .
;


proc sql;
create table allvar1 as
select distinct var1 from raw;
create table allnames as
select distinct name from raw;
create table temp as
select name,var1  from allname ,allvar1
order by name,var1;
quit;
proc sort data=raw;
by name var1;
run;

data result;
merge temp (in=a) raw;
by name var1;
if a;
run;

shiyiming

no no no!
hash not needed.
just one data step ,not include hash !

shiyiming

受不了了，BYES老大给点提示吧...

shiyiming

oloolo方法不错，不过需要sort。

two set in one data step can do it according to byes' idea ？